build.gradle

plugins {
  id 'java-library'
  id 'maven-publish'
  id 'signing'
}

version = '2024.0.0-beta-1'

repositories {
  mavenCentral()

  maven { url 'https://frcmaven.wpi.edu/artifactory/release/' }
  maven { url 'https://maven.ctr-electronics.com/release/' }
  maven { url 'https://maven.revrobotics.com/' }
  maven { url 'https://dev.studica.com/maven/release/2024/' }
}

dependencies {
  // Current GradleRIO versions at https://github.com/wpilibsuite/GradleRIO/blob/main/src/main/java/edu/wpi/first/gradlerio/wpi/WPIVersionsExtension.java
  String wpilibVersion = '2024.1.1-beta-3'
  String jacksonVersion = '2.12.4'
  String ejmlVersion = '0.43.1'

  String navxVersion = '2024.0.1-beta-3' // https://dev.studica.com/releases/2024/NavX.json
  String phoenix5Version = '5.32.0-beta-1' // https://maven.ctr-electronics.com/release/com/ctre/phoenix/Phoenix5-frc2024-beta-latest.json
  String phoenix6Version = '24.0.0-beta-1' // https://maven.ctr-electronics.com/release/com/ctre/phoenix6/latest/Phoenix6-frc2024-beta-latest.json
  String revlibVersion = '2024.0.0' // https://software-metadata.revrobotics.com/REVLib-2024.json

  compileOnly 'edu.wpi.first.wpilibj:wpilibj-java:' + wpilibVersion
  compileOnly 'edu.wpi.first.ntcore:ntcore-java:' + wpilibVersion
  compileOnly 'edu.wpi.first.hal:hal-java:' + wpilibVersion
  compileOnly 'edu.wpi.first.wpinet:wpinet-java:' + wpilibVersion
  compileOnly 'edu.wpi.first.wpiutil:wpiutil-java:' + wpilibVersion
  compileOnly 'edu.wpi.first.wpilibNewCommands:wpilibNewCommands-java:' + wpilibVersion
  compileOnly 'edu.wpi.first.wpimath:wpimath-java:' + wpilibVersion
  compileOnly 'com.fasterxml.jackson.core:jackson-annotations:' + jacksonVersion
  compileOnly 'org.ejml:ejml-ddense:' + ejmlVersion

  compileOnly 'com.kauailabs.navx.frc:navx-frc-java:' + navxVersion
  compileOnly 'com.ctre.phoenix:api-java:' + phoenix5Version
  compileOnly 'com.ctre.phoenix:wpiapi-java:' + phoenix5Version
  compileOnly 'com.ctre.phoenix6:wpiapi-java:' + phoenix6Version
  compileOnly 'com.revrobotics.frc:REVLib-java:' + revlibVersion

  testImplementation 'org.junit.jupiter:junit-jupiter:5.9.1'
}

test {
  useJUnitPlatform()
}

java {
  sourceCompatibility = JavaVersion.VERSION_17
  targetCompatibility = JavaVersion.VERSION_17
}

javadoc {
  options.addBooleanOption('html5', true)
}

jar {
  dependsOn javadoc
  from sourceSets.main.allJava
  from javadoc.destinationDir
  archiveFileName = 'dtlib.jar'
}

task sourcesJar(type: Jar) {
  from sourceSets.main.allJava
  archiveClassifier = 'sources'
}

task javadocJar(type: Jar) {
  dependsOn javadoc
  from javadoc.destinationDir
  archiveClassifier = 'javadoc'
}

publishing {
  publications {
    mavenCentral(MavenPublication) {
      groupId = 'org.victorrobotics.dtlib'
      artifactId = 'dtlib-java'
      version = project.version

      from components.java
      artifact sourcesJar
      artifact javadocJar

      pom {
        name = 'DTLib'
        description = 'An extension of WPILib developed by FRC Team 1559'
        url = 'http://github.com/Team1559/DTLib'
        inceptionYear = '2023'

        licenses {
          license {
            name = 'MIT License'
            url = 'https://opensource.org/license/mit/'
          }
        }

        organization {
          name = 'Victor Robotics - FRC Team 1559'
          url = 'https://victorrobotics.org'
        }

        developers {
          developer {
            name = 'Alexander Bhalla'
            email = 'xander.bhalla@gmail.com'
            url = 'https://github.com/MathNerd28'
          }
        }

        scm {
          connection = 'scm:git:git://github.com/Team1559/DTLib.git'
          developerConnection = 'scm:git:ssh://github.com:Team1559/DTLib.git'
          url = 'https://github.com/Team1559/DTLib/tree/master'
        }
      }
    }
  }

  repositories {
    maven {
      name = 'OSSRH'
      url = 'https://s01.oss.sonatype.org/service/local/staging/deploy/maven2/'
      credentials {
        username = System.getenv('DTLIB_PUBLISH_USERNAME')
        password = System.getenv('DTLIB_PUBLISH_PASSWORD')
      }
    }
  }
}

signing {
  useGpgCmd()
  sign publishing.publications.mavenCentral
}