waterway_nomod.brf

---context:global   # following code refers to global config

assign   validForFoot             0   # helps to get a time variable, limit is foot speed, not variable
assign   validForBikes            1   # helps to get a time variable
assign   validForCars             0
assign   validForBoat             1   # this is a nice to have, does nothing

assign   shortest_way             1   # %shortest_way% | use the shortest way | boolean

assign   speed_normal             10  # %speed_normal% | Speed in kmh | number

assign   flow_rate                0   # %flow_rate% | Flow on a river in kmh | number

# my boat has max speed
assign   maxSpeed                 18  # km/h (Caution: this is case sensitive internal parameter and different to maxspeed)
                                      # handle with care, this belongs to your local area and your boat

assign   processUnusedTags        0   # lists all (incl. unused) key/value pairs in geojson
assign   showspeed                1   # show speed instead of elevation (geojson)

# Turn instructions settings
assign considerTurnRestrictions     = true
assign turnInstructionMode          = 4     # Mode for the generated turn instructions | [0=none, 1=auto-choose, 2=locus-style, 3=osmand-style, 4=comment-style, 5=gpsies-style, 6=orux-style]
assign turnInstructionCatchingRange = 40    # Within this distance (in m) several turning instructions are combined into one and the turning angles are better approximated to the general direction | number
assign turnInstructionRoundabouts   = false # Set to "false" to avoid generating special turning instructions for roundabouts | boolean

assign   waiting_lock 			  900    # in seconds, for one lock_gate
assign   waiting_bridge			  900    # in seconds
assign   around_time			  900    # in seconds, avoid obstacles

assign   notdefined               100000


---context:way   # following code refers to way-tags


assign not_used
	switch boat=no                        true
	switch boat=private				      true
	switch access=private				  true
    switch access=no                      true
	false

assign is_waterway
	switch waterway=river|canal|fairway|lock       true
	switch seamark:type=fairway|recommended_track  true
	switch boat=yes|permissive|designated          true
	switch motorboat=yes                           true
	false
	
assign maxspeed 
    switch and is_waterway not_used                   0
    switch and waterway=river reversedirection=yes    sub speed_normal flow_rate
    switch     waterway=river                         add speed_normal flow_rate
    switch     is_waterway                            speed_normal
	speed_normal

	
assign turncost        0

assign initialcost     0


assign costfactor
	switch and is_waterway not_used    		notdefined
	switch waterway=lock    		        10
	switch is_waterway              		1
	notdefined
		


---context:node  # following code refers to node tags


assign initialcost 
	switch waterway=lock_gate|lock  waiting_lock
	0