forked from xydan83/open62541-nodeset-exporter
-
Notifications
You must be signed in to change notification settings - Fork 0
/
Copy pathCMakeLists.txt
364 lines (314 loc) · 15.4 KB
/
CMakeLists.txt
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
#
# This Source Code Form is subject to the terms of the Mozilla Public
# License, v. 2.0. If a copy of the MPL was not distributed with this
# file, You can obtain one at http://mozilla.org/MPL/2.0/.
#
# Copyright 2024 (c) Aleksander Rozhkov <[email protected]>
#
cmake_minimum_required(VERSION 3.18)
project(nodesetexporter
VERSION 1.1.0
HOMEPAGE_URL "https://github.com/xydan83/open62541-nodeset-exporter"
LANGUAGES C CXX)
set(PROJECT_VERSION_SUFFIX "alpha")
include(GNUInstallDirs)
# -------------BUILD OPTIONS-------------
# Set default build type.
option(CMAKE_BUILD_TYPE "Build type " Release)
# Set the option to enable code using a performance timer
option(NODESETEXPORTER_PERFORMANCE_TIMER_ENABLED "Add performance timer code" OFF)
# (optional) Use the Conan package manager to download, build, and install dependencies for specific versions.
option(NODESETEXPORTER_CONAN_ENABLE "Use Conan package manager for resolving project dependencies" ON)
# This option allows you to disable the build of tests from the default build.
option(NODESETEXPORTER_BUILD_TESTS "Include tests in build" OFF)
# This option allows you to create a command utility that can export a set of nodes from the OPC UA Server node space.
option(NODESETEXPORTER_CLI_ENABLE "Add nodesetexporter command utility to build" OFF)
# If you want to add the open62541 library as a static submodule.
option(NODESETEXPORTER_OPEN62541_IS_SUBMODULE "Switch ON this if Open62541 is included as a submodule (built-in) as a static library" OFF)
# If present and true, this will cause all libraries to be built shared unless the library was explicitly added as a static library.
option(BUILD_SHARED_LIBS "Build shared library" OFF)
# ---------------------------------------
set(BUILD_TESTING ${NODESETEXPORTER_BUILD_TESTS})
# Installing the C++ Language Standard
set(CMAKE_CXX_STANDARD 20)
set(CMAKE_CXX_STANDARD_REQUIRED ON)
# Set compiler flags.
set(CMAKE_CXX_FLAGS_DEBUG_INIT "-Wall -Werror")
set(CMAKE_CXX_FLAGS_RELEASE_INIT "-Wall -Werror")
# Set default build type.
if (NOT CMAKE_BUILD_TYPE)
message(STATUS "CMAKE_BUILD_TYPE is not set. Set it to 'Release' by default.")
set(CMAKE_BUILD_TYPE "Release")
endif ()
# Enable link-time optimizations for the release build.
if (CMAKE_BUILD_TYPE MATCHES "^(Release|RelWithDebInfo|MinSizeRel)$")
set(CMAKE_INTERPROCEDURAL_OPTIMIZATION TRUE)
endif ()
# Enable CMake to save executed commands to a file.
# For more details see: http://clang.llvm.org/docs/HowToSetupToolingForLLVM.html
set(CMAKE_EXPORT_COMPILE_COMMANDS ON)
configure_file(
include/nodesetexporter/Build.h.in
include/nodesetexporter/Build.h
@ONLY
)
# Connect Clang extensions.
include(.cmake/ClangFormat.cmake)
include(.cmake/ClangTidy.cmake)
if (${NODESETEXPORTER_CONAN_ENABLE})
include(.cmake/Conan.cmake)
# Install Conan configuration (repositories, profiles, etc.).
conan_config_install(ITEM ${CMAKE_SOURCE_DIR}/.conan/config)
# Install dependencies using Conan.
conan_cmake_run(
CONANFILE .conan/conanfile.txt
BASIC_SETUP CMAKE_TARGETS
BUILD missing
GENERATORS cmake_find_package
ENV CC=${CMAKE_C_COMPILER} CXX=${CMAKE_CXX_COMPILER}
)
include(${CMAKE_BINARY_DIR}/conanbuildinfo.cmake)
conan_basic_setup()
set(CMAKE_MODULE_PATH ${CMAKE_BINARY_DIR} ${CMAKE_MODULE_PATH})
set(CMAKE_PREFIX_PATH ${CMAKE_BINARY_DIR} ${CMAKE_PREFIX_PATH})
#
# # Do not include external libraries supplied by Conan in the analysis.
foreach (CONAN_MODULE_PATH ${CONAN_CMAKE_MODULE_PATH})
set(CONNECTORS_COVERAGE_EXCLUDES ${CONNECTORS_COVERAGE_EXCLUDES} "${CONAN_MODULE_PATH}/*")
endforeach ()
endif ()
# Connect the Boost library
set(Boost_USE_STATIC_LIBS ON)
find_package(
Boost
1.79.0
REQUIRED
COMPONENTS
program_options
)
add_definitions(-DBOOST_ALLOW_DEPRECATED_HEADERS)
# Connect Python3
find_package(Python3 REQUIRED)
set(PYTHON_EXECUTABLE ${Python3_EXECUTABLE})
# Connect the FMT lightweight text formatting library
find_package(fmt)
if (fmt_FOUND)
message(STATUS "fmt package has been found.")
add_compile_definitions(USING_FMT)
endif ()
# Connect OPC-UA Open62541 as a shared library
if (NOT ${NODESETEXPORTER_OPEN62541_IS_SUBMODULE})
find_package(open62541)
endif ()
# Since in the Open62541 library, from some version (or commit), the UA_print function produces the result in quotes,
# when the definition is activated, the quotes will be removed. (necessary for compatibility).
# add_compile_definitions(OPEN62541_UAPRINT_WITH_QUOTES)
# Connect the Microsoft Standards Library
find_package(GSL)
# Connect the static reflection library for enum
find_package(magic_enum)
if (NODESETEXPORTER_PERFORMANCE_TIMER_ENABLED)
message("Performance timer code has been added to nodesetexporter.")
add_compile_definitions(PERFORMANCE_TIMER_ENABLED)
endif ()
# Generating associative containers of name aliases to TypeNodeID (DataType, ReferenceType)
set(UA_FILE_NODEIDS ${PROJECT_SOURCE_DIR}/toolchain/NodeIds.csv)
set(UA_FILE_NODEIDS_GEN_UTIL ${PROJECT_SOURCE_DIR}/toolchain/aliases_map_maker.py)
set(UA_STATUS_CODE_DATATYPE_HEADER_DIR ${CMAKE_BINARY_DIR}/include/nodesetexporter/common)
set(UA_STATUS_CODE_DATATYPE_HEADER_FILENAME DatatypeAliases.h)
# Loading NodeIds.csv from a opcfoundation.org resource
if (NOT EXISTS ${UA_FILE_NODEIDS})
file(DOWNLOAD https://raw.githubusercontent.com/OPCFoundation/UA-Nodeset/v1.04/Schema/NodeIds.csv ${UA_FILE_NODEIDS} SHOW_PROGRESS)
endif ()
# Header file generation
if (NOT EXISTS "${UA_FILE_NODEIDS}")
message(FATAL_ERROR "File not found ${UA_FILE_NODEIDS}")
endif ()
if (NOT EXISTS "${UA_FILE_NODEIDS_GEN_UTIL}")
message(FATAL_ERROR "A utility for generating a name alias file for TypeNodeID was not found (DataType, ReferenceType): ${UA_FILE_NODEIDS_GEN_UTIL}")
endif ()
file(MAKE_DIRECTORY ${UA_STATUS_CODE_DATATYPE_HEADER_DIR})
execute_process(
COMMAND ${PYTHON_EXECUTABLE} ${UA_FILE_NODEIDS_GEN_UTIL} --nodeids_path ${UA_FILE_NODEIDS} --path_to_header ${UA_STATUS_CODE_DATATYPE_HEADER_DIR}/${UA_STATUS_CODE_DATATYPE_HEADER_FILENAME}
TIMEOUT 60
ERROR_VARIABLE CMD_ERROR)
if (${CMD_ERROR})
message(FATAL_ERROR "The status code file could not be generated. Script error code: ${CMD_ERROR}")
endif ()
# Forming the nodesetexporter library
set(NODESETEXPORTER_INTERNAL_PUBLIC_HEADERS
$<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include/nodesetexporter/interfaces/IEncoder.h>
$<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include/nodesetexporter/interfaces/IOpen62541.h>
$<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include/nodesetexporter/encoders/GetAttributeToXMLText.h>
$<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include/nodesetexporter/encoders/XMLEncoder.h>
$<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include/nodesetexporter/open62541/UATypesContainer.h>
$<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include/nodesetexporter/open62541/ClientWrappers.h>
$<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include/nodesetexporter/open62541/ServerWrappers.h>
$<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include/nodesetexporter/open62541/TypeAliases.h>
$<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include/nodesetexporter/open62541/NodeIntermediateModel.h>
$<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include/nodesetexporter/open62541/BrowseOperations.h>
$<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include/nodesetexporter/logger/StdLog.h>
$<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include/nodesetexporter/logger/LogPlugin.h>
$<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include/nodesetexporter/NodesetExporter.h>
$<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include/nodesetexporter/NodesetExporterLoop.h>
$<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include/nodesetexporter/common/LoggerBase.h>
$<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include/nodesetexporter/common/Statuses.h>
$<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include/nodesetexporter/common/Encoder_types.h>
$<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include/nodesetexporter/common/Strings.h>
$<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include/nodesetexporter/common/PerformanceTimer.h>
$<BUILD_INTERFACE:${CMAKE_BINARY_DIR}/include/nodesetexporter/common/DatatypeAliases.h>
CACHE INTERNAL "")
set(NODESETEXPORTER_INTERNAL_PRIVATE_SOURCE
${CMAKE_CURRENT_SOURCE_DIR}/src/nodesetexporter/open62541/TypeAliases.cpp
${CMAKE_CURRENT_SOURCE_DIR}/src/nodesetexporter/open62541/BrowseOperations.cpp
${CMAKE_CURRENT_SOURCE_DIR}/src/nodesetexporter/open62541/ClientWrappers.cpp
${CMAKE_CURRENT_SOURCE_DIR}/src/nodesetexporter/NodesetExporterLoop.cpp
${CMAKE_CURRENT_SOURCE_DIR}/src/nodesetexporter/NodesetExporter.cpp
${CMAKE_CURRENT_SOURCE_DIR}/src/nodesetexporter/logger/LogPlugin.cpp
CACHE INTERNAL "")
# Forming the nodesetexporter library for cli utility and for tests
if (${NODESETEXPORTER_CLI_ENABLE} OR ${NODESETEXPORTER_BUILD_TESTS})
add_library(${PROJECT_NAME}-for-cli STATIC)
target_sources(
${PROJECT_NAME}-for-cli
PUBLIC
${NODESETEXPORTER_INTERNAL_PUBLIC_HEADERS}
PRIVATE
${NODESETEXPORTER_INTERNAL_PRIVATE_SOURCE}
)
target_include_directories(
${PROJECT_NAME}-for-cli
PUBLIC
$<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include/>
$<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include/nodesetexporter/>
$<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include/nodesetexporter/common/>
$<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include/nodesetexporter/open62541/>
$<BUILD_INTERFACE:${CMAKE_BINARY_DIR}/include/>
)
target_link_libraries(
${PROJECT_NAME}-for-cli
PRIVATE
open62541::open62541
tinyxml2
magic_enum::magic_enum
fmt::fmt
)
endif ()
add_library(${PROJECT_NAME})
target_sources(
${PROJECT_NAME}
PUBLIC
${NODESETEXPORTER_INTERNAL_PUBLIC_HEADERS}
PRIVATE
${NODESETEXPORTER_INTERNAL_PRIVATE_SOURCE}
)
target_include_directories(
${PROJECT_NAME}
PUBLIC
$<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include/>
$<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include/nodesetexporter/>
$<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include/nodesetexporter/common/>
$<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include/nodesetexporter/open62541/>
$<BUILD_INTERFACE:${CMAKE_BINARY_DIR}/include/>
$<INSTALL_INTERFACE:include>
)
target_link_libraries(
${PROJECT_NAME}
PRIVATE
open62541::open62541
tinyxml2
magic_enum::magic_enum
fmt::fmt
)
# Setting up the test part of the project
# Downloading UANodeSet.xsd from opcfoundation.org
if (NOT EXISTS ${PROJECT_SOURCE_DIR}/test/nodesetexporter/server_nodeset/UANodeSet.xsd)
file(DOWNLOAD https://raw.githubusercontent.com/OPCFoundation/UA-Nodeset/v1.04/Schema/UANodeSet.xsd ${PROJECT_SOURCE_DIR}/test/nodesetexporter/server_nodeset/UANodeSet.xsd SHOW_PROGRESS)
endif ()
# Forming the tests
if (${NODESETEXPORTER_BUILD_TESTS})
include(CTest)
enable_testing()
include(.cmake/Tests.cmake)
# Connect a library of unit tests
find_package(doctest)
# Connect a library of mocks for testing
find_package(trompeloeil)
# Finding a Dynamic Library for the xml nodeset test
find_library(XMLPLUSPLUS NAMES xml++-5.0)
message("libxml++ path: " ${XMLPLUSPLUS})
SET_SOURCE_FILES_PROPERTIES(${CMAKE_CURRENT_SOURCE_DIR}/test/nodesetexporter/server_nodeset/ex_nodeset.c PROPERTIES COMPILE_FLAGS -O0)
add_executable(
${PROJECT_NAME}-tests
${CMAKE_CURRENT_SOURCE_DIR}/test/nodesetexporter/open62541/UATypesContainerTest.cpp
${CMAKE_CURRENT_SOURCE_DIR}/test/nodesetexporter/open62541/NodeIntermediateModelTest.cpp
${CMAKE_CURRENT_SOURCE_DIR}/test/nodesetexporter/open62541/TypeAliasesTest.cpp
${CMAKE_CURRENT_SOURCE_DIR}/test/nodesetexporter/open62541/StdLogTest.cpp
${CMAKE_CURRENT_SOURCE_DIR}/test/nodesetexporter/open62541/ClientWrappersTest.cpp
${CMAKE_CURRENT_SOURCE_DIR}/test/nodesetexporter/open62541/BrowseOperationsTest.cpp
${CMAKE_CURRENT_SOURCE_DIR}/test/nodesetexporter/encoders/XMLEncoderTest.cpp
${CMAKE_CURRENT_SOURCE_DIR}/test/nodesetexporter/common/PerformanceTimerTest.cpp
${CMAKE_CURRENT_SOURCE_DIR}/test/nodesetexporter/NodesetExporterLoopTest.cpp
${CMAKE_CURRENT_SOURCE_DIR}/test/nodesetexporter/NodesetExporterTest.cpp
)
target_sources(
${PROJECT_NAME}-tests
PUBLIC
${CMAKE_CURRENT_SOURCE_DIR}/test/nodesetexporter/server_nodeset/ex_nodeset.h
${CMAKE_CURRENT_SOURCE_DIR}/test/nodesetexporter/common_for_tests/XmlHelperFunctions.h
${CMAKE_CURRENT_SOURCE_DIR}/include/nodesetexporter/open62541/UATypesContainer.h
PRIVATE
${CMAKE_CURRENT_SOURCE_DIR}/test/nodesetexporter/server_nodeset/ex_nodeset.c
)
target_include_directories(
${PROJECT_NAME}-tests
PUBLIC
${CMAKE_CURRENT_SOURCE_DIR}/test/nodesetexporter/server_nodeset
${CMAKE_CURRENT_SOURCE_DIR}/test/nodesetexporter/common_for_tests
${CMAKE_BINARY_DIR}/include/
)
target_link_libraries(
${PROJECT_NAME}-tests
PRIVATE
${PROJECT_NAME}-for-cli
lib-testing
doctest::doctest
trompeloeil::trompeloeil
magic_enum::magic_enum
tinyxml2
${XMLPLUSPLUS})
if (fmt_FOUND)
target_link_libraries(
${PROJECT_NAME}-tests
PRIVATE
fmt::fmt)
endif ()
# Copying UANodeSet.xsd for encoder test
file(MAKE_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
configure_file(test/nodesetexporter/server_nodeset/UANodeSet.xsd ${CMAKE_BINARY_DIR}/bin COPYONLY)
configure_file(test/nodesetexporter/server_nodeset/UANodeSet.xsd ${CMAKE_CURRENT_BINARY_DIR} COPYONLY)
add_unit_test(NAME ${PROJECT_NAME}-tests)
endif ()
# Connecting the assembly of the executable export utility.
if (${NODESETEXPORTER_CLI_ENABLE})
add_subdirectory(apps)
endif ()
# Connecting auxiliary libraries
add_subdirectory(lib)
# Install nodesetexporter library
set(NODESETEXPORTER_EXPORT_PUBLIC_HEADERS
${PROJECT_SOURCE_DIR}/include/nodesetexporter/NodesetExporter.h
${PROJECT_SOURCE_DIR}/include/nodesetexporter/common/Encoder_types.h
${PROJECT_SOURCE_DIR}/include/nodesetexporter/common/LoggerBase.h
${PROJECT_SOURCE_DIR}/include/nodesetexporter/open62541/UATypesContainer.h
${PROJECT_SOURCE_DIR}/include/nodesetexporter/common/Statuses.h
CACHE INTERNAL "")
set_target_properties(${PROJECT_NAME} PROPERTIES PUBLIC_HEADER "${NODESETEXPORTER_EXPORT_PUBLIC_HEADERS}")
install(TARGETS ${PROJECT_NAME}
EXPORT NodesetExporter
LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
PUBLIC_HEADER DESTINATION include/NodesetExporter)
install(FILES nodesetexporter-config.cmake DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/NodesetExporter)
install(EXPORT NodesetExporter DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/NodesetExporter)