feat(languages): Lean experimental tree-sitter-lean

.gitmodules

@@ -190,6 +190,10 @@
 	path = helix-syntax/languages/tree-sitter-git-rebase
 	url = https://github.com/the-mikedavis/tree-sitter-git-rebase.git
 	shallow = true
+[submodule "helix-syntax/languages/tree-sitter-lean"]
+	path = helix-syntax/languages/tree-sitter-lean
+	url = https://github.com/Julian/tree-sitter-lean
+	shallow = true
 [submodule "helix-syntax/languages/tree-sitter-regex"]
 	path = helix-syntax/languages/tree-sitter-regex
 	url = https://github.com/tree-sitter/tree-sitter-regex.git

book/src/generated/lang-support.md

@@ -23,6 +23,7 @@
 | json | ✓ |  | ✓ |  |
 | julia | ✓ |  |  | `julia` |
 | latex | ✓ |  |  |  |
+| lean | ✓ |  |  | `lean` |
 | ledger | ✓ |  |  |  |
 | llvm | ✓ | ✓ | ✓ |  |
 | llvm-mir | ✓ | ✓ | ✓ |  |

languages.toml

@@ -241,6 +241,17 @@ comment-token = "%"
 
 indent = { tab-width = 4, unit = "\t" }
 
+[[language]]
+name = "lean"
+scope = "source.lean"
+injection-regex = "lean"
+file-types = ["lean"]
+roots = [ "lakefile.lean" ]
+comment-token = "--"
+language-server = { command = "lean", args = [ "--server" ] }
+
+indent = { tab-width = 2, unit = "  " }
+
 [[language]]
 name = "julia"
 scope = "source.julia"

runtime/queries/lean/folds.scm

@@ -0,0 +1,15 @@
+[
+  (namespace)
+  (section)
+
+  (instance)
+  (def)
+  (theorem)
+  (example)
+
+  (product)
+  (array)
+  (list)
+
+  (string)
+] @fold

runtime/queries/lean/highlights.scm

@@ -0,0 +1,217 @@
+(open
+  namespace: (identifier) @namespace)
+(namespace
+  name: (identifier) @namespace)
+(section
+  name: (identifier) @namespace)
+
+; Variables
+(identifier) @variable
+
+;; Identifier naming conventions
+((identifier) @type
+ (#match? @type "^[A-Z]"))
+
+(arrow) @type
+(product) @type
+
+;; Declarations
+
+[
+  "abbrev"
+  "def"
+  "theorem"
+  "constant"
+  "instance"
+  "axiom"
+  "example"
+  "inductive"
+  "structure"
+  "class"
+
+  "deriving"
+
+  "section"
+  "namespace"
+] @keyword
+
+(attributes
+  (identifier) @function)
+
+(abbrev
+  name: (identifier) @type)
+(def
+  name: (identifier) @function)
+(theorem
+  name: (identifier) @function)
+(constant
+  name: (identifier) @type)
+(instance
+  name: (identifier) @function)
+(instance
+  type: (identifier) @type)
+(axiom
+  name: (identifier) @function)
+(structure
+  name: (identifier) @type)
+(structure
+  extends: (identifier) @type)
+
+(where_decl
+  type: (identifier) @type)
+
+(proj
+  name: (identifier) @field)
+
+(binders
+  type: (identifier) @type)
+
+["if" "then" "else"] @keyword.control.conditional
+
+["for" "in" "do"] @keyword.control.repeat
+
+(import) @include
+
+; Tokens
+
+[
+  "!"
+  "$"
+  "%"
+  "&&"
+  "*"
+  "*>"
+  "+"
+  "++"
+  "-"
+  "/"
+  "::"
+  ":="
+  "<"
+  "<$>"
+  "<*"
+  "<*>"
+  "<="
+  "<|"
+  "<|>"
+  "="
+  "=="
+  "=>"
+  ">"
+  ">"
+  ">="
+  ">>"
+  ">>="
+  "@"
+  "^"
+  "|>"
+  "|>."
+  "||"
+  "←"
+  "→"
+  "↔"
+  "∘"
+  "∧"
+  "∨"
+  "≠"
+  "≤"
+  "≥"
+] @operator
+
+[
+  "@&"
+] @operator
+
+[
+  "attribute"
+  "by"
+  "end"
+  "export"
+  "extends"
+  "fun"
+  "let"
+  "have"
+  "match"
+  "open"
+  "return"
+  "universe"
+  "variable"
+  "where"
+  "with"
+  "λ"
+  (hash_command)
+  (prelude)
+  (sorry)
+] @keyword
+
+[
+  "prefix"
+  "infix"
+  "infixl"
+  "infixr"
+  "postfix"
+  "notation"
+  "macro_rules"
+  "syntax"
+  "elab"
+  "builtin_initialize"
+] @keyword
+
+[
+  "noncomputable"
+  "partial"
+  "private"
+  "protected"
+  "unsafe"
+] @keyword
+
+[
+  "apply"
+  "exact"
+  "rewrite"
+  "rw"
+  "simp"
+  (trivial)
+] @keyword
+
+[
+  "catch"
+  "finally"
+  "try"
+] @exception
+
+((apply
+  name: (identifier) @exception)
+ (#match? @exception "throw"))
+
+[
+  "unless"
+  "mut"
+] @keyword
+
+[(true) (false)] @boolean
+
+(number) @constant.numeric.integer
+(float) @constant.numeric.float
+
+(comment) @comment
+(char) @character
+(string) @string
+(interpolated_string) @string
+; (escape_sequence) @string.escape
+
+; Reset highlighing in string interpolation
+(interpolation) @none
+
+(interpolation
+  "{" @punctuation.special
+  "}" @punctuation.special)
+
+["(" ")" "[" "]" "{" "}" "⟨" "⟩"] @punctuation.bracket
+
+["|" "," "." ":" ";"] @punctuation.delimiter
+
+(sorry) @error
+
+;; Error
+(ERROR) @error

runtime/queries/lean/injections.scm

@@ -0,0 +1,2 @@
+((comment) @markdown
+  (#offset! @markdown 0 3 0 -2))

runtime/queries/lean/locals.scm

@@ -0,0 +1,3 @@
+(module) @scope
+(namespace) @scope
+(section) @scope