How to create more specified custom search commands?

[AnabasisXu]

In my previous post, I have integrated Everything and RGA into consult-locate and consult-ripgrep.
Integration of Everything and Riggrep-all into Consult · minad/consult · Discussion #1172

The problem is that now these commands are taken, and I can not further specify more search commands. For instance, I want to search only path, not files. I can either type -path . foobar, or I can make it easier by (setq consult-locate-args "es -sort date-modified-descending -path ."). But the later option means I only search path with consult-locate.
Can I keep consult-locate for files and create consult-locate-path for only path?

---

2025-02-05 update:
Bellow is a simple config to wrap consult-everything to create consult-everything-dir which only search for directories, and consult-everything-local to only search for local files.

TODO: not sure how to get -r and folder: work together. es -r folder:emacs.+d works on the command line, but not with consult-everything.

	(use-package consult
		:config
		(defcustom consult-everything-args
			"es -r"
			"Command line arguments for everything, see `consult-everything'.

The default value is \"es -r\", which only works if you place the command line version of Everything (es.exe) in your PATH."
			:type 'string)

		(defun consult--everything-builder (input)
			"Build command line from INPUT."
			(pcase-let ((`(,arg . ,opts) (consult--command-split input)))
				(unless (string-blank-p arg)
					(cons (append (consult--build-args consult-everything-args)
												(consult--split-escaped arg) opts)
								(cdr (consult--default-regexp-compiler input 'basic t))))))

		(defun consult-everything (&optional initial)
			"Search with `everything' for files matching input regexp given INITIAL input."
			(interactive)
			(find-file (consult--find "Everything: " #'consult--everything-builder initial)))

		(defun consult-everything-dir (&optional initial)
			"Search for directory using Everything."
			(interactive)
			(let ((consult-everything-args "es -sort date-modified-descending folder:"))
				(consult-everything initial)))

		(defun consult-everything-local (&optional initial)
			"Search for files in the current directory using Everything."
			(interactive)
			(let ((consult-everything-args "es -path ."))
				(consult-everything initial)))

[minad]

You could create separate commands wrapping consult-locate and let-bind consult-locate-args around the call to consult-locate. Would that work?

[AnabasisXu]

Hi @minad , thanks for quick response. Sorry my Elisp skill remain quite primitive. Is there any template for wrapping consul-locate commands and let-bind consult-locate-args?

[minad]

Yes, I think there are plenty of examples in the Consult wiki.